Tjackson82@aol.com wrote:
>
> I believe there is a formula for roughly figuring your top speed that
> involves computing the size of the tire, the rear axle ratio and the engine
> RPMs. Can anyone help?
Terry:
Here is the old Basic program I wrote to do the calculations. It can
run on any version of Basic - including that on an old 8088 processor
(am I dating myself?). Anyway, if you know Basic, you can edit this to
produce your own set of gear charts - if you need help, I can provide
that too!!
Ok, here goes ...
10 REM TITLE DETERMINE SPEED BASED ON TIRE SIZE AND GEARS
20 REM SUBTITLE No Bozos Racing Software
30 RE=4.428571 ' Rear-end ratio
40 DIM GR(5) ' Gearset in use
follows
50 GR(2)=34/18 : GR(3)=29/22 : GR(4)=26/25 : GR(5)=24/28
60 REM Input the tire size to be used as a variable
70 PRINT "" : PRINT "Enter Tire Diameter (in inches) or '0' to exit: ";
80 INPUT D : IF D=0 THEN STOP ELSE C# = D*3.141592
85 CV#=C#*5/5280/RE ' Conversion factor: 5 = 60/12
(sec./inches)
90 PRINT " NO BOZOS RACING" : PRINT ""
100 PRINT " Gear/Tire Speed Calculations" : PRINT "" : PRINT ""
110 PRINT "Tire Diameter: "; : PRINT D;: PRINT "Rear-End Ratio: "; :
PRINT RE
120 PRINT "" : PRINT " RPM 18:34 22:29 25:26 29:24" : PRINT ""
130 REM Display speed in each gear in 500 RPM increments.
140 FOR RPM% = 1000 TO 9000 STEP 500
150 PRINT RPM%;
160 FOR G% = 2 TO 5
170 REM Calculate MPH as tire circumference * RPMs * 60
(seconds/minute)
180 REM divided by 12 (inches/foot) divided by 5280 (feet per mile)
190 REM divided by gear ratio divided by rear-end ratio
200 MPH#=CV#*RPM%/GR(G%)
210 PRINT USING "#####.##";MPH#; : NEXT G%
220 PRINT ""
230 NEXT RPM%
240 PRINT "" : PRINT "Print these results (Y/N)? "; : LINE INPUT A$
250 IF A$ = "Y" THEN GOSUB 280
260 GOTO 70
270 REM Print results just displayed on the screen.
280 LPRINT " NO BOZOS RACING" : LPRINT ""
290 LPRINT " Gear/Tire Speed Calculations" : LPRINT "" : LPRINT ""
300 LPRINT "Tire Diameter: "; : LPRINT D;: LPRINT "Rear-End Ratio: "; :
LPRINT RE
310 LPRINT "" : LPRINT " RPM 18:34 22:29 25:26 29:24" : LPRINT
""
320 FOR RPM% = 1000 TO 9000 STEP 500
330 LPRINT RPM%;
340 FOR G% = 2 TO 5
350 MPH#=CV#*RPM%/GR(G%)
360 LPRINT USING "#####.##";MPH#; : NEXT G%
370 LPRINT ""
380 NEXT RPM% : LPRINT "" : LPRINT "" : RETURN
When you the say RUN it will ask you for your tire diameter and off you
go!! You will have to provide your own differential ratio and gears in
the above code, but after that, just pick your tire sizes... Good Luck!
*8o)
|